// -*- povray -*-
// Time-stamp: <Teddy Hogeborn February  5, 2000 05:22:35>

#version 3.0

global_settings {
  assumed_gamma 1.0
}

background {
//  color rgbf <0,0,0,1> // Black
  color rgbf <1,1,1,1> // White
//  color rgbf <192/255, 192/255, 192/255, 1> // Netscape background grey
//  color rgbf <214/255, 214/255, 214/255, 1> // GTK grey
}

// Camera definition
camera {
  orthographic
  location < 0, 0, 22 >
  right 20*x
//  right 24*x // When animating (rotating) it needs more room
  up 13*y
//  up 20*y  // Square image, for the NeXT and GAG icons
//  up (24/1.4)*y // XBill OS icon
  look_at < 0, 0, 6 >
}

// Instances

light_source {
  < 60, 60, 30 >
  color rgb 1
}

// Big blue sphere
#declare Big_blue_sphere =
sphere { <0,0,0>, 6
  texture {
    pigment
      { color rgb <0, 0, 1> }
//      { color rgb <0, 0, 192/255> } // PC 16 colors
    finish {
      diffuse 1
      ambient 0.5
      specular 0.6
      reflection 0.2
//	diffuse 0 // PC 16 colors
//	ambient 1
//	specular 0
//	reflection 0
    }
  }
}

#declare Texttexture =
texture {
  pigment { color rgb <0, .8, 0> }
//  pigment { color rgb <0, 192/255, 0> } // PC 16 colors
  finish {
    diffuse 1
    ambient 0.5
//    diffuse 0 // PC 16 colors
//    ambient 1
    specular 0
    reflection 0
  }
}

#declare H_left_stem =
union {
  sphere { <1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <1.5, 2, 0>,  // Center of one end
    <1.5, -2, 0>, // Center of other end
    0.5             // Radius
    texture { Texttexture }
  }
  sphere { <1.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare H_right_stem =
union {
  sphere { <-1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <-1.5, 2, 0>,  // Center of one end
    <-1.5, -2, 0>, // Center of other end
    0.5              // Radius
    texture { Texttexture }
  }
  sphere { <-1.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare H_middle_bar =
cylinder {
  <1.5, 0, 0>,  // Center of one end
  <-1.5, 0, 0>, // Center of other end
  0.5             // Radius
  texture { Texttexture }
}

#declare Letter_H =
union {
  object { H_left_stem }
  object { H_right_stem }
  object { H_middle_bar }
}

#declare U_left_stem =
union {
  sphere { <1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <1.5, 2, 0>,   // Center of one end
    <1.5, -.5, 0>, // Center of other end
    0.5            // Radius
    texture { Texttexture }
  }
  sphere { <1.5, -.5, 0> .5
    texture { Texttexture }
  }
}

#declare U_right_stem =
union {
  sphere { <-1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <-1.5, 2, 0>,   // Center of one end
    <-1.5, -.5, 0>, // Center of other end
    0.5             // Radius
    texture { Texttexture }
  }
  sphere { <-1.5, -.5, 0> .5
    texture { Texttexture }
  }
}

#declare U_lower_bend =
difference {
  torus {
    1.5, .5
    sturm
    texture { Texttexture }
    rotate x*90
    translate <0, -.5, 0>
  }
  box { <2.5, 2, 1>, <-2.5, -.5, -1>
    texture { Texttexture }
  }
}

#declare Letter_U =
union {
  object { U_left_stem }
  object { U_right_stem }
  object { U_lower_bend }
}

#declare R_left_stem =
union {
  sphere { <1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <1.5, 2, 0>,  // Center of one end
    <1.5, -2, 0>, // Center of other end
    0.5           // Radius
    texture { Texttexture }
  }
  sphere { <1.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare R_upper_bar =
union {
  cylinder {
    <1.5, 2, 0>, // Center of one end
    <-.5, 2, 0>, // Center of other end
    0.5          // Radius
    texture { Texttexture }
  }
  sphere { <-.5, 2, 0> .5
    texture { Texttexture }
  }
}

#declare R_middle_bar =
union {
  cylinder {
    <1.5, 0, 0>, // Center of one end
    <-.5, 0, 0>, // Center of other end
    0.5          // Radius
    texture { Texttexture }
  }
  sphere { <-.5, 0, 0> .5
    texture { Texttexture }
  }
}

#declare R_upper_right_bend =
difference {
  torus {
    1, .5
    sturm
    texture { Texttexture }
    rotate x*90
    translate <-.5, 1, 0>
  }
  box { <1.5, 3, 1>, <-.5, -1, -1>
    texture { Texttexture }
  }
}

#declare R_lower_right_branch =
union {
  cylinder {
    <.5, 0, 0>,    // Center of one end
    <-1.5, -2, 0>, // Center of other end
    0.5            // Radius
    texture { Texttexture }
  }
  sphere { <-1.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare Letter_R =
union {
  object { R_left_stem }
  object { R_upper_bar }
  object { R_middle_bar }
  object { R_upper_right_bend }
  object { R_lower_right_branch }
}

#declare D_left_stem =
union {
  sphere { <1.5, 2, 0> .5
    texture { Texttexture }
  }
  cylinder {
    <1.5, 2, 0>,  // Center of one end
    <1.5, -2, 0>, // Center of other end
    0.5           // Radius
    texture { Texttexture }
  }
  sphere { <1.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare D_upper_bar =
union {
  cylinder {
    <1.5, 2, 0>, // Center of one end
    <.5, 2, 0>,  // Center of other end
    0.5          // Radius
    texture { Texttexture }
  }
  sphere { <.5, 2, 0> .5
    texture { Texttexture }
  }
}

#declare D_lower_bar =
union {
  cylinder {
    <1.5, -2, 0>, // Center of one end
    <.5, -2, 0>,  // Center of other end
    0.5           // Radius
    texture { Texttexture }
  }
  sphere { <.5, -2, 0> .5
    texture { Texttexture }
  }
}

#declare D_right_bend =
difference {
  torus {
    2, .5
    sturm
    texture { Texttexture }
    rotate x*90
    translate <.5, 0, 0>
  }
  box { <3.5, 3, 1>, <.5, -3, -1>
    texture { Texttexture }
  }
}

#declare Letter_D =
union {
  object { D_left_stem }
  object { D_upper_bar }
  object { D_lower_bar }
  object { D_right_bend }
}

#declare HURD_text =
union {
  object { Letter_H  translate <7.5, 0, 0> }
  object { Letter_U  translate <2.5, 0, 0> }
  object { Letter_R  translate <-2.5, 0, 0> }
  object { Letter_D  translate <-7.5, 0, 0> }
}

#declare HURD_logo =
union {
  object { Big_blue_sphere }
  object { HURD_text  translate <0, 0, 6.5> }
}

object {
  HURD_logo
  rotate 360*clock*y
}